[VBA] 팝빌 전자세금계산서 SDK 튜토리얼

MS Access 환경에서 팝빌 VBA SDK를 적용하여 전자세금계산서 즉시발행(RegistIssue API) 함수를 구현하는 예시입니다.

1. Popbill 클래스모듈 추가

① 팝빌 연동자료실에서 MS Access SDK 예제코드 다운로드 후 압축을 해제합니다.

② 압축해제한 전자세금계산서 서비스 Access 예제파일에 포함된 클래스 모듈을 기존 프로젝트의 클래스 모듈로 추가합니다.

팝빌 VBA SDK Example

③ Window 폼 코드에 인증정보와 클래스를 선언하고 Form_Load() 서브모듈에 전자세금계산서 클래스 초기화 코드를 추가합니다.

연동신청시 발급받은 인증정보로 링크아이디(LinkID)와 비밀키(SecretKey) 값을 변경하시기 바랍니다.

Form 인증정보, 클래스 객체 선언


Option Explicit

' 링크아이디, 연동신청시 발급받은 정보로 수정
Private Const LinkID = "TESTER"

' 비밀키, 연동신청시 발급받은 정보로 수정
Private Const SecretKey = "SwWxqU+0TErBXy/9TVjIPEnI0VTUMMSQZtJf3Ed8q3I="

' 세금계산서 서비스 클래스 변수 선언
Private TaxinvoiceService As New PBTIService

Form_Load() 서브모듈


Private Sub Form_Load()
  ' 세금계산서 서비스 클래스 초기화
  TaxinvoiceService.Initialize LinkID, SecretKey

  ' 연동환경 설정값 True(개발용), False(상업용), 상업용 전환시 False로 변경.
  TaxinvoiceService.IsTest = True
End Sub

2. 전자세금계산서 즉시발행(RegistIssue API) 함수 구현

① Form에 버튼을 생성하고 버튼의 Click Event 코드에 전자세금계산서 즉시발행 함수(RegistIssue)를 작성합니다.


Private Sub btnRegistIssue_Click()
    Dim Taxinvoice As New PBTaxinvoice
    Dim corpNum As String

    corpNum = "1234567890"

    '[필수] 작성일자, 표시형식 (yyyyMMdd) ex)20190207
    Taxinvoice.writeDate = "20190903"

    '[필수] 발행형태, [정발행, 역발행, 위수탁] 중 기재
    Taxinvoice.IssueType = "정발행"

    '[필수] {정과금, 역과금} 중 기재, '역과금'은 역발행 프로세스에서만 이용가능
    '- 정과금(공급자 과금), 역과금(공급받는자 과금)
    Taxinvoice.chargeDirection = "정과금"

    '[필수] 영수/청구, [영수, 청구] 중 기재
    Taxinvoice.purposeType = "영수"

    '[필수] 발행시점
    Taxinvoice.issueTiming = "직접발행"

    '[필수] 과세형태, [과세, 영세, 면세] 중 기재
    Taxinvoice.taxType = "과세"


    '=========================================================================
    '                              공급자 정보
    '=========================================================================

    '[필수] 공급자 사업자번호, '-' 제외 10자리
    Taxinvoice.invoicerCorpNum = corpNum

    '[필수] 공급자 종사업장 식별번호. 필요시 숫자 4자리 기재
    Taxinvoice.invoicerTaxRegID = ""

    '[필수] 공급자 상호
    Taxinvoice.invoicerCorpName = "공급자 상호"

    '[필수] 공급자 문서관리번호, 1~24자리 (숫자, 영문, '-', '_') 조합으로
    '사업자 별로 중복되지 않도록 구성
    Taxinvoice.invoicerMgtKey = "20190903-011"

    '[필수] 공급자 대표자 성명
    Taxinvoice.invoicerCEOName = "공급자 대표자 성명"

    '공급자 주소
    Taxinvoice.invoicerAddr = "공급자 주소"

    '공급자 업태
    Taxinvoice.invoicerBizType = "공급자 업태,업태2"

    '공급자 종목
    Taxinvoice.invoicerBizClass = "공급자 종목"

    '공급자 담당자명
    Taxinvoice.invoicerContactName = "공급자 담당자명"

    '공급자 담당자 메일주소
    Taxinvoice.invoicerEmail = "test@test.com"

    '공급자 담당자 연락처
    Taxinvoice.invoicerTEL = "070-7070-0707"

    '공급자 담당자 휴대폰번호
    Taxinvoice.invoicerHP = "010-000-2222"

    ' 발행시 알림문자 전송여부 (정발행에서만 사용가능)
    ' - 공급받는자 주)담당자 휴대폰번호(invoiceeHP1)로 전송
    ' - 전송시 포인트가 차감되며 전송실패하는 경우 포인트 환불처리
    Taxinvoice.invoicerSMSSendYN = False


    '=========================================================================
    '                            공급받는자 정보
    '=========================================================================

    '[필수] 공급받는자 구분, [사업자, 개인, 외국인] 중 기재
    Taxinvoice.invoiceeType = "사업자"

    '[필수] 공급받는자 사업자번호, '-' 제외 10자리
    Taxinvoice.invoiceeCorpNum = "8888888888"

    '[필수] 공급받는자 종사업장 식별번호. 필요시 숫자 4자리 기재
    Taxinvoice.invoiceeTaxRegID = ""

    '[필수] 공급자받는자 상호
    Taxinvoice.invoiceeCorpName = "공급받는자 상호"

    '[역발행시 필수] 공급받는자 문서관리번호(역발행시 필수)
    Taxinvoice.invoiceeMgtKey = ""

    '[필수] 공급받는자 대표자 성명
    Taxinvoice.invoiceeCEOName = "공급받는자 대표자 성명"

    '공급받는자 주소
    Taxinvoice.invoiceeAddr = "공급받는자 주소"

    '공급받는자 종목
    Taxinvoice.invoiceeBizClass = "공급받는자 업종"

    '공급받는자 업태
    Taxinvoice.invoiceeBizType = "공급받는자 업태"

    '공급받는자 담당자명
    Taxinvoice.invoiceeContactName1 = "공급받는자 담당자명"

    '공급받는자 담당자 메일주소
    Taxinvoice.invoiceeEmail1 = "test@invoicee.com"

    '공급받는자 담당자 연락처
    Taxinvoice.invoiceeTEL1 = "070-1234-1234"

    '공급받는자 담당자 휴대폰번호
    Taxinvoice.invoiceeHP1 = "010-111-222"


    '=========================================================================
    '                            세금계산서 정보
    '=========================================================================

    '[필수] 공급가액 합계
    Taxinvoice.supplyCostTotal = "200000"

    '[필수] 세액 합계
    Taxinvoice.taxTotal = "20000"

    '[필수] 합계금액, 공급가액 합계 + 세액합계
    Taxinvoice.totalAmount = "220000"

    '기재 상 '일련번호' 항목
    Taxinvoice.serialNum = "123"

    '기재 상 '권' 항목, 최대값 32767
    '미기재시 Taxinvoice.kwon = ""
    Taxinvoice.kwon = "1"

    '기재 상 '호' 항목, 최대값 32767
    '미기재시 Taxinvoice.kwon = ""
    Taxinvoice.ho = "1"

    '기재 상 '현금' 항목
    Taxinvoice.cash = ""

    '기재 상 '수표' 항목
    Taxinvoice.chkBill = ""

    '기재 상 '어음' 항목
    Taxinvoice.note = ""

    '기재 상 '외상미수금' 항목
    Taxinvoice.credit = ""

    '기재 상 '비고'항목
    Taxinvoice.remark1 = "비고1"
    Taxinvoice.remark2 = "비고2"
    Taxinvoice.remark3 = "비고3"

    '사업자등록증 이미지 첨부여부
    Taxinvoice.businessLicenseYN = False

    '통장사본 이미지 첨부여부
    Taxinvoice.bankBookYN = False


    '=========================================================================
    '         수정세금계산서 정보 (수정세금계산서 작성시에만 기재
    ' - 수정세금계산서 관련 정보는 연동매뉴얼 또는 개발가이드 링크 참조
    ' - [참고] 수정세금계산서 작성방법 안내 - http://blog.linkhub.co.kr/650
    '========================================================================='

    ' 수정사유코드, 수정사유에 따라 1~6중 선택기재
    Taxinvoice.modifyCode = ""

    ' 원본세금계산서의 ItemKey, 문서확인 (GetInfo API)의 응답결과(ItemKey 항목) 확인
    Taxinvoice.originalTaxinvoiceKey = ""


    '=========================================================================
    '             상세항목(품목) 정보 > 배열로 99개까지 기재 가능
    '=========================================================================

    Set Taxinvoice.detailList = New Collection

    Dim newDetail As New PBTIDetail

    newDetail.serialNum = 1             '일련번호 1부터 순차 기재
    newDetail.purchaseDT = "20190903"   '거래일자  yyyyMMdd
    newDetail.itemName = "품명"         '품목명
    newDetail.spec = "규격"             '규격
    newDetail.qty = "1"                 '수량
    newDetail.unitCost = "100000"       '단가
    newDetail.supplyCost = "100000"     '공급가액
    newDetail.tax = "10000"             '세액
    newDetail.remark = "비고"           '비고

    Taxinvoice.detailList.Add newDetail

    Dim newDetail2 As New PBTIDetail
    newDetail2.serialNum = 2             '일련번호 1부터 순차 기재
    newDetail2.purchaseDT = "20190903"   '거래일자  yyyyMMdd
    newDetail2.itemName = "품명2"        '품목명
    newDetail2.spec = "규격"             '규격
    newDetail2.qty = "1"                 '수량
    newDetail2.unitCost = "100000"       '단가
    newDetail2.supplyCost = "100000"     '공급가액
    newDetail2.tax = "10000"             '세액
    newDetail2.remark = "비고"           '비고

    Taxinvoice.detailList.Add newDetail2


    '=========================================================================
    '             추가담당자 정보 > 배열로 5개까지 기재 가능
    ' - 세금계산서 발행안내 메일을 수신받을 공급받는자 담당자가 다수인 경우
    ' 담당자 정보를 추가하여 발행안내메일을 다수에게 전송할 수 있습니다.
    '=========================================================================

    Set Taxinvoice.addContactList = New Collection
    Dim newContact As New PBTIContact
    newContact.serialNum = 1                 '일련번호, 1부터 순차기재
    newContact.contactName = "담당자 성명"   '담당자명
    newContact.email = "test2@test.com"      '담당자 메일주소
    Taxinvoice.addContactList.Add newContact

    Dim newContact2 As New PBTIContact
    newContact2.serialNum = 2                '일련번호, 1부터 순차기재
    newContact2.contactName = "담당자 성명"  '담당자명
    newContact2.email = "test2@test.com"     '담당자 메일주소
    Taxinvoice.addContactList.Add newContact2


    '거래명세서 동시작성 여부
    Taxinvoice.writeSpecification = False

    '거래명세서 동시작성시 거래명세서 관리번호, 미기재시 세금계산서 관리번호로 자동작성
    Taxinvoice.dealInvoiceMgtKey = ""

    '지연발행 강제여부(forceIssue)
    '발행마감일이 지난 세금계산서를 발행하는 경우, 가산세가 부과될 수 있습니다.
    '가산세가 부과되더라도 발행을 해야하는 경우에는 forceIssue의 값을 true로 선언하면 됩니다.
    Taxinvoice.forceIssue = False

    '메모
    Taxinvoice.Memo = ""

    '발행안내 메일제목, 공백처리시 기본제목으로 전송
    Taxinvoice.emailSubject = ""


    Dim Response As PBResponse

    Set Response = TaxinvoiceService.RegistIssue(corpNum, Taxinvoice)

    If Response Is Nothing Then
        MsgBox ("응답코드 : " + CStr(TaxinvoiceService.LastErrCode) + vbCrLf + "응답메시지 : " + TaxinvoiceService.LastErrMessage)
        Exit Sub
    End If

    MsgBox ("응답코드 : " + CStr(Response.code) + vbCrLf + "응답메시지 : " + Response.message + vbCrLf + "국세청 승인번호 : " + Response.ntsConfirmNum)
End Sub

② 버튼 클릭으로 함수호출 결과를 확인합니다.

팝빌 VBA SDK 전자세금계산서 Example

기술지원센터

팝빌 기술지원은 유선, 메일, 원격지원 등 다양한 채널을 통해 제공됩니다.

T. 1600-9854   E. code@linkhub.co.kr

연동문의