[VBA] 팝빌 전자명세서 SDK 튜토리얼

MS Access 환경에서 팝빌 VBA SDK를 적용하여 전자명세서 즉시발행(RegistIssue API) 함수를 구현하는 예시입니다.

1. Popbill 클래스모듈 추가

① 팝빌 연동자료실에서 MS Access SDK 예제코드 다운로드 후 압축을 해제합니다.

② 압축해제한 전자명세서 서비스 Access 예제파일에 포함된 클래스 모듈을 기존 프로젝트의 클래스 모듈로 추가합니다.

팝빌 VBA SDK Example

③ Window 폼 코드에 인증정보와 클래스를 선언하고 Form_Load() 서브모듈에 전자명세서 클래스 초기화 코드를 추가합니다.

연동신청시 발급받은 인증정보로 링크아이디(LinkID)와 비밀키(SecretKey) 값을 변경하시기 바랍니다.

Form 인증정보, 클래스 객체 선언


Option Explicit

' 링크아이디, 연동신청시 발급받은 정보로 수정
Private Const LinkID = "TESTER"

' 비밀키, 연동신청시 발급받은 정보로 수정
Private Const SecretKey = "SwWxqU+0TErBXy/9TVjIPEnI0VTUMMSQZtJf3Ed8q3I="

' 전자명세서 서비스 클래스 변수 선언
Private statementService As New PBDocService

Form_Load() 서브모듈


Private Sub Form_Load()
  ' 전자명세서 서비스 클래스 객체 초기화
  statementService.Initialize LinkID, SecretKey

  ' 연동환경설정값, True-개발용 False-상업용
  statementService.IsTest = True
End Sub

2. 전자명세서 즉시발행(RegistIssue API) 함수 구현

① Form에 버튼을 생성하고 버튼의 Click Event 코드에 전자명세서 즉시발행 함수(RegistIssue)를 작성합니다.


Private Sub btnRegistIssue_Click()
    Dim Statement As New PBStatement
    Dim newDetail As PBDocDetail
    Dim Response As PBResponse
    Dim i
    Dim corpNum As String

    '팝빌회원 사업자번호
    corpNum = "1234567890"

    Statement.memo = "즉시발행 메모"

    '[필수] 기재상 작성일자, 날자형식(yyyyMMdd)
    Statement.writeDate = "20190903"

    '[필수] {영수, 청구} 중 기재
    Statement.purposeType = "영수"

    '[필수] 과세형태, {과세, 영세, 면세} 중 기재
    Statement.taxType = "과세"

    '맞춤양식코드, 공백처리시 기본양식으로 작성
    Statement.formCode = ""

    '[필수] 전자명세서 종류코드
    Statement.itemCode = 121

    '[필수] 문서관리번호, 숫자, 영문, '-', '_' 조합 (최대24자리)으로 사업자별로 중복되지 않도록 구성
    Statement.mgtKey = "20190903-021"


    '=========================================================================
    '                               공급자 정보
    '=========================================================================

    '공급자 사업자번호, '-' 제외 10자리
    Statement.senderCorpNum = corpNum

    '공급자 종사업장 식별번호, 필요시 기재, 형식은 숫자 4자리
    Statement.senderTaxRegID = ""

    '공급자 상호
    Statement.senderCorpName = "공급자 상호"

    '공급자 상호명
    Statement.senderCEOName = "공급자 대표자 성명"

    '공급자 주소
    Statement.senderAddr = "공급자 주소"

    '공급자 종목
    Statement.senderBizClass = "공급자 종목"

    '공급자 업태
    Statement.senderBizType = "공급자 업태,업태2"

    '공급자 담당자성명
    Statement.senderContactName = "공급자 담당자명"

    '공급자 이메일
    Statement.senderEmail = "test@test.com"

    '공급자 연락처
    Statement.senderTEL = "070-7070-0707"

    '공급자 휴대전화 번호
    Statement.senderHP = "010-000-2222"


    '=========================================================================
    '                        공급받는자 정보
    '=========================================================================

    '공급받는자 사업자번호, '-' 제외 10자리
    Statement.receiverCorpNum = "8888888888"

    '공급받는자 상호
    Statement.receiverCorpName = "공급받는자 상호"

    '공급받는자 대표자 성명
    Statement.receiverCEOName = "공급받는자 대표자 성명"

    '공급받는자 주소
    Statement.receiverAddr = "공급받는자 주소"

    '공급받는자 종목
    Statement.receiverBizClass = "공급받는자 종목 "

    '공급받는자 업태
    Statement.receiverBizType = "공급받는자 업태"

    '공급받는자 담당자명
    Statement.receiverContactName = "공급받는자 담당자명"

    '공급받는자 메일주소
    Statement.receiverEmail = "test@receiver.com"

    '=========================================================================
    '                     전자명세서 기재사항
    '=========================================================================

    '[필수] 공급가액 합계
    Statement.supplyCostTotal = "100000"

    '[필수] 세액 합계
    Statement.taxTotal = "10000"

    '[필수] 합계금액, 공급가액 합계 + 세액 합계
    Statement.totalAmount = "110000"             '필수 합계금액.  공급가액 + 세액

    '기재 상 일련번호 항목
    Statement.serialNum = "123"

    '기재 상 비고 항목
    Statement.remark1 = "비고1"
    Statement.remark2 = "비고2"
    Statement.remark3 = "비고3"

    '사업자등록증 이미지 첨부여부
    Statement.businessLicenseYN = False

    '통장사본 이미지 첨부여부
    Statement.bankBookYN = False

    '발행시 알림문자 발송여부
    Statement.smssendYN = True

    '상세항목 추가.
    Set Statement.detailList = New Collection

    For i = 1 To 20

        Set newDetail = New PBDocDetail

        newDetail.serialNum = i             '일련번호 1부터 순차 기재
        newDetail.purchaseDT = "20190903"   '거래일자  yyyyMMdd
        newDetail.itemName = "품명" + CStr(i)
        newDetail.spec = "규격"
        newDetail.unit = "단위"
        newDetail.qty = "1" '수량           ' 소숫점 2자리까지 문자열로 기재가능
        newDetail.unitCost = "100000"       ' 소숫점 2자리까지 문자열로 기재가능
        newDetail.supplyCost = "100000"
        newDetail.tax = "10000"
        newDetail.remark = "비고"
        newDetail.spare1 = "spare1"
        newDetail.spare2 = "spare2"
        newDetail.spare3 = "spare3"
        newDetail.spare4 = "spare4"
        newDetail.spare5 = "spare5"

        Statement.detailList.Add newDetail

    Next

    '=========================================================================
    '전자명세서 추가속성
    ' - 추가속성에 관한 자세한 사항은 "[전자명세서 API 연동매뉴얼] >
    '   5.2. 기본양식 추가속성 테이블"을 참조하시기 바랍니다.
    '=========================================================================

    Set Statement.propertyBag = CreateObject("Scripting.Dictionary")

    Statement.propertyBag.Add "CBalance", "100000"
    Statement.propertyBag.Add "Deposit", "10000"
    Statement.propertyBag.Add "Balance", "100000"

    Set Response = statementService.RegistIssue(corpNum, Statement)

    If Response Is Nothing Then
        MsgBox ("응답코드 : " + CStr(statementService.LastErrCode) + vbCrLf + "응답메시지 : " + statementService.LastErrMessage)
        Exit Sub
    End If

    MsgBox ("응답코드 : " + CStr(Response.code) + vbCrLf + "응답메시지 : " + Response.message)
End Sub

② 버튼 클릭으로 함수호출 결과를 확인합니다.

팝빌 VBA SDK 전자명세서 Example

기술지원센터

팝빌 기술지원은 유선, 메일, 원격지원 등 다양한 채널을 통해 제공됩니다.

T. 1600-9854   E. code@linkhub.co.kr

연동문의