[Visual Basic] 팝빌 팩스 SDK 튜토리얼

Visual Basic 환경에서 팝빌 Visual Basic SDK를 적용하여 팩스 전송(SendFAX API) 함수를 구현하는 예시입니다.

1. Popbill 클래스모듈 추가

① 팝빌 연동자료실에서 Visual Basic SDK 예제코드 다운로드 후 압축을 해제합니다.

② 압축해제한 SDK 예제 프로젝트의 Linkhub/ Popbill/ 폴더에 포함된 클래스모듈을 기존 프로젝트의 클래스모듈로 추가합니다.

팝빌 Visual Basic SDK Example

③ Window 폼 코드에 인증정보와 클래스를 선언하고 Form_Load() 서브모듈에 팩스 클래스 초기화 코드를 추가합니다.

연동신청시 발급받은 인증정보로 링크아이디(LinkID)와 비밀키(SecretKey) 값을 변경하시기 바랍니다.

Form 인증정보, 클래스 객체 선언


Option Explicit

' 링크아이디, 연동신청시 발급받은 정보로 수정
Private Const LinkID = "TESTER"

' 비밀키, 연동신청시 발급받은 정보로 수정
Private Const SecretKey = "SwWxqU+0TErBXy/9TVjIPEnI0VTUMMSQZtJf3Ed8q3I="

' 팩스 서비스 클래스 변수 선언
Private FaxService As New PBFAXService

Form_Load() 서브모듈


Private Sub Form_Load()
  ' 팩스 서비스 클래스 객체 초기화
  FaxService.Initialize LinkID, SecretKey

  ' 연동환경 설정값 True(테스트용), False(상업용)
  FaxService.IsTest = True
End Sub

2. 팩스 전송(SendFAX API) 함수 구현

① Form에 버튼을 생성하고 버튼의 Click Event 코드에 팩스 전송 함수(SendFAX)를 작성합니다.


Private Sub btnSendFAX_Click()
    Dim FilePaths As New Collection
    Dim senderNum As String
    Dim senderName As String
    Dim receivers As New Collection
    Dim receiver As New PBReceiver
    Dim receiptNum As String
    Dim adsYN As Boolean
    Dim title As String
    Dim requestNum As String
    Dim corpNum As String
    Dim userID As String
    Dim reserveDT As String

    '팝빌회원 사업자번호
    corpNum = "1234567890"

    '팝빌회원 아이디
    userID = "testkorea"

    CommonDialog1.fileName = ""

    CommonDialog1.ShowOpen

    If CommonDialog1.fileName = "" Then Exit Sub

    FilePaths.Add CommonDialog1.fileName

    '발신번호
    senderNum = "07043042991"

    '발신자명
    senderName = "발신자명"

    '수신번호
    receiver.receiverNum = "070111222"

    '수신자명
    receiver.receiverName = "수신자 명칭"
    receivers.Add receiver

    '광고팩스 전송여부
    adsYN = False

    '팩스제목
    title = "팩스 단건전송 제목"

    '예약전송일시
    reserveDT = ""

    '전송요청번호, 파트너가 전송요청에 대한 관리번호를 직접 할당하여 관리하는 경우 기재
    '최대 36자리, 영문, 숫자, 언더바('_'), 하이픈('-')을 조합하여 사업자별로 중복되지 않도록 구성
    requestNum = ""

    receiptNum = FaxService.SendFAX(corpNum, senderNum, receivers, FilePaths, reserveDT, userID, senderName, adsYN, title, requestNum)

    If receiptNum = "" Then
        MsgBox ("응답코드 : " + CStr(FaxService.LastErrCode) + vbCrLf + "응답메시지 : " + FaxService.LastErrMessage)
        Exit Sub
    End If

    MsgBox "접수번호 : " + receiptNum

End Sub

② 버튼 클릭으로 함수호출 결과를 확인합니다.

팝빌 Visual Basic SDK 팩스 Example

기술지원센터

팝빌 기술지원은 유선, 메일, 원격지원 등 다양한 채널을 통해 제공됩니다.

T. 1600-9854   E. code@linkhub.co.kr

연동문의